*&---------------------------------------------------------------------*
*& Report  Zsysmess                                                    *
*&---------------------------------------------------------------------*

REPORT  zsysmess  .

INCLUDE <icon>.
TABLES: usr03.


************************************************************************
DATA hlp_str LIKE tgsus-output.
DATA: BEGIN OF COMMON PART usr.
DATA: BEGIN OF usr_tabl OCCURS 10.
        INCLUDE STRUCTURE uinfo.
*DATA:   name1 LIKE usr03-name1,
*        name2 LIKE usr03-name2,
DATA: END OF usr_tabl.
DATA: END OF COMMON PART usr.
DATA: opcode TYPE x.
DATA: hlp_mand LIKE uinfo-mandt.
DATA: hlp_user LIKE uinfo-bname.

************************************************************************
PARAMETERS pa_text LIKE tgsus-output.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) text-001.
SELECTION-SCREEN PUSHBUTTON 35(4) pushbttn USER-COMMAND help.
SELECTION-SCREEN COMMENT 40(3) txt_mand.
SELECTION-SCREEN COMMENT 45(10) txt_user.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN SKIP.
PARAMETERS pa_anz(3) TYPE n OBLIGATORY DEFAULT 1.

************************************************************************
INITIALIZATION.
  WRITE icon_employee AS ICON TO pushbttn.

************************************************************************
AT SELECTION-SCREEN.
  IF sy-ucomm = 'HELP'.
    PERFORM f4_hilfe.
  ENDIF.

************************************************************************
START-OF-SELECTION.

  MOVE pa_text  TO hlp_str.
  MOVE txt_mand TO hlp_mand.
  MOVE txt_user TO hlp_user.

* Selbstschutz

  CHECK NOT hlp_mand IS INITIAL.
  CHECK NOT hlp_user IS INITIAL.

  DO pa_anz TIMES.

    CALL FUNCTION 'TH_POPUP'
      EXPORTING
        client         = hlp_mand
        user           = hlp_user
        MESSAGE        = hlp_str
      EXCEPTIONS
        user_not_found = 1
        OTHERS         = 2.
    IF NOT sy-subrc = 0.
      EXIT.
    ENDIF.
  ENDDO.

*&---------------------------------------------------------------------*
*&      Form  F4_HILFE
*&---------------------------------------------------------------------*
FORM f4_hilfe.
  DATA: hlp_index LIKE smeinh-zaehler.

  DATA: BEGIN OF ld_hlpvalues OCCURS 100,
          line(30) TYPE c,
        END OF ld_hlpvalues.
  DATA: BEGIN OF ld_hlpfields OCCURS 100.
          INCLUDE STRUCTURE help_value.
  DATA: END OF ld_hlpfields.

  opcode = 2.
  REFRESH usr_tabl.
  CALL 'ThUsrInfo' ID 'OPCODE' FIELD opcode
    ID 'TAB' FIELD usr_tabl-*sys*.


* Feldertabelle vorbereiten ...
  MOVE 'SMEINH' TO ld_hlpfields-tabname.
  MOVE 'ZAEHLER' TO ld_hlpfields-fieldname.
  MOVE 'X'   TO ld_hlpfields-selectflag.
  APPEND ld_hlpfields.

  MOVE 'UINFO' TO ld_hlpfields-tabname.
  MOVE 'BNAME' TO ld_hlpfields-fieldname.
  MOVE ' '   TO ld_hlpfields-selectflag.
  APPEND ld_hlpfields.

  MOVE 'UINFO' TO ld_hlpfields-tabname.
  MOVE 'MANDT' TO ld_hlpfields-fieldname.
  MOVE ' '     TO ld_hlpfields-selectflag.
  APPEND ld_hlpfields.

  LOOP AT usr_tabl.
    MOVE sy-tabix       TO ld_hlpvalues-line.
    SHIFT ld_hlpvalues-line LEFT DELETING LEADING space.
    APPEND ld_hlpvalues.

    MOVE usr_tabl-bname TO ld_hlpvalues-line.
    APPEND ld_hlpvalues.

    MOVE usr_tabl-mandt TO ld_hlpvalues-line.
    APPEND ld_hlpvalues.

  ENDLOOP.

* F4-Hilfe aufrufen
  CALL FUNCTION 'HELP_VALUES_GET_WITH_TABLE'
    IMPORTING
      select_value              = hlp_index
    TABLES
      fields                    = ld_hlpfields
      valuetab                  = ld_hlpvalues
    EXCEPTIONS
      field_not_in_ddic         = 1
      more_then_one_selectfield = 2
      no_selectfield            = 3
      OTHERS                    = 4.

  READ TABLE usr_tabl INDEX hlp_index.
  MOVE usr_tabl-bname TO txt_user.
  MOVE usr_tabl-mandt TO txt_mand.

ENDFORM.                                                    "f4_hilfe